*Datensatz ALLBUS 2010 (A10) laden (Ordnerpfad muss natürlich individuell angepasst werden)*

GET FILE="C:\Meine Daten\Uni\M.A. Soziologie\WiSe 2011_12\Lehre\Multivariate Analyseverfahren\ALLBUS 2010\ZA4610_A10.SAV".

*Datensatz A10 auf die interessierenden Variablen reduzieren und in einem neuen Datensatz speichern (Ordnerpfad muss natürlich individuell angepasst werden)*

MATCH FILES FILE * /KEEP v2 v5 v298 v301 v327 v348 v362 v612 v977.

SAVE OUTFILE="C:\Meine Daten\Uni\M.A. Soziologie\WiSe 2011_12\Lehre\Multivariate Analyseverfahren\Übung Giacinto 22.11.11\A10_Analyse.SAV"
/COMPRESSED.

***DATENAUFBEREITUNG***

*Datensatz gewichten mit Variable Personenbezogenes-Ost-West-Gewicht (v977)*

WEIGHT BY v977.

*Dummysierung (0-/1-Kodierung) Geschlecht v298 in v298_d*

RECODE v298 (1=0) (2=1) INTO v298_d.
VALUE LABELS v298_d 0 'Mann' 1 'Frau'.
VARIABLE LABELS v298_d 'Geschlecht_d'.
EXECUTE.

*Konsistenzcheck alte und neue Variable Geschlecht (v298&v298_d)*

FREQUENCIES VARIABLES=v298 v298_d
  /STATISTICS=MINIMUM MAXIMUM
  /ORDER=ANALYSIS.

*Dummysierung (0-/1-Kodierung) Erhebungsgebiet-Ost-West v5 in v5_d*

RECODE v5 (1=0) (2=1) INTO v5_d.
VALUE LABELS v5_d 0 'West' 1 'Ost'.
VARIABLE LABELS v5_d 'Erhebungsgebiet_d'.
EXECUTE.

*Konsistenzcheck alte und neue Variable Erhebungsgebiet-Ost-West (v5&v5_d)*

FREQUENCIES VARIABLES=v5 v5_d
  /STATISTICS=MINIMUM MAXIMUM
  /ORDER=ANALYSIS.


*Rekodierung Variable Allgemeiner Schulabschluss  (Ausschluss von 'Noch Schüler' und 'Anderer Abschluss' zu systembedingt fehlenden Werten, 
so dass fünf ordinalskalierte bzw. quasimetrische Antwortkategorien vorliegen) v327 in v327_neu für Regressionsmodell II*

RECODE v327 (1=1) (2=2) (3=3) (4=4) (5=5) (6=SYSMIS) (7=SYSMIS) (99=SYSMIS) INTO v327_neu.
VALUE LABELS v327_neu 1 'Kein Schulabschluss' 2 'Haupt-,Volksschulabschluss' 3 'Mittlere Reife' 4 'Fachhochschulreife' 5 'Hochschulreife'.
VARIABLE LABELS v327_neu 'Allgemeiner Schulabschluss_neu'.
EXECUTE. 


*Konsistenzcheck alte und neue Variable Allgemeiner Schulabschluss (v327&v327_neu)*

FREQUENCIES VARIABLES=v327 v327_neu
  /STATISTICS=MINIMUM MAXIMUM
  /ORDER=ANALYSIS.


*Rekodierung Variable Allgemeiner Schulabschluss v327 zu (n-1)-Schulabschluss_Dummy-Variablen für Regressionsmodel I*

COMPUTE Kein_Abschluss_d2 = v327=1. 
VALUE LABELS Kein_Abschluss_d2 0 'nicht genannt' 1 'genannt'.
VARIABLE LABELS Kein_Abschluss_d2 'Kein_Abschluss_Dummy'.
EXECUTE.

COMPUTE Haupt_Volksschulabschluss_d3 = v327=2. 
VALUE LABELS Haupt_Volksschulabschluss_d3 0 'nicht genannt' 1 'genannt'.
VARIABLE LABELS Haupt_Volksschulabschluss_d3 'Haupt_Volksschulabschluss_Dummy'.
EXECUTE.

COMPUTE Mittlere_Reife_d4 = v327=3. 
VALUE LABELS Mittlere_Reife_d4 0 'nicht genannt' 1 'genannt'.
VARIABLE LABELS Mittlere_Reife_d4 'Mittlere_Reife_Dummy'.
EXECUTE.

COMPUTE Fachhochschulreife_d5 = v327=4. 
VALUE LABELS Fachhochschulreife_d5 0 'nicht genannt' 1 'genannt'.
VARIABLE LABELS Fachhochschulreife_d5 'Fachhochschulreife_Dummy'.
EXECUTE.

*Konsistenzcheck alte und neue Variable Schulabschluss (v327&Kein_Abschluss_d2&Haupt_Volksschulabschluss_d3&Mittlere_Reife_d4&Fachhochschulreife_d5)*

FREQUENCIES VARIABLES=v327 Kein_Abschluss_d2 Haupt_Volksschulabschluss_d3 Mittlere_Reife_d4 Fachhochschulreife_d5
  /STATISTICS=MINIMUM MAXIMUM
  /ORDER=ANALYSIS.


***DATENANALYSE***

**UNIVARIATE DATENANALYSE DER ABHÄNGIGEN VARIABLE**

FREQUENCIES VARIABLES=v612
  /FORMAT=NOTABLE
  /STATISTICS=STDDEV MINIMUM MAXIMUM MEAN SKEWNESS KURTOSIS
  /HISTOGRAM NORMAL
  /ORDER=ANALYSIS.


**KORRELATION DER STETIGEN VARIABLEN**

CORRELATIONS
  /VARIABLES=v612 v301 v348 v362 v327_neu 
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE.

**SCATTERPLOTT NETTOEINKOMMEN&MAGNITUDEPRESTIGE (graphische Darstellung des ungerichteten positiven Zusammenhangs)**


GRAPH
  /SCATTERPLOT(BIVAR)=v348 WITH v612
  /MISSING=LISTWISE.


GRAPH
  /SCATTERPLOT(BIVAR)=v612 WITH v348
  /MISSING=LISTWISE.


*Personenbezogenes Ost-West-Gewicht deaktivieren*

WEIGHT OFF.

*Multiples Regressionsmodell  I mit Schulabschluss-Dummys*

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /REGWGT=v977
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT v612
  /METHOD=ENTER v301 v298_d v5_d v348 v362 Kein_Abschluss_d2 Haupt_Volksschulabschluss_d3 
    Mittlere_Reife_d4 Fachhochschulreife_d5.



*Multiples Regressionsmodell II ohne Schulabschluss-Dummys*

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /REGWGT=v977
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT v612
  /METHOD=ENTER v301 v298_d v5_d v348 v362 v327_neu.